===== Установка =====
==== Локальная ====
<code dos>
rem Задаём путь к папке дистрибутива
set opk-docs=%userprofile%\Desktop\opk-docs

rem Устанавливаем компоненты
msiexec /i "%opk-docs%\Prerequisites.msi" /qn ALLUSERS=1
msiexec /i "%opk-docs%\DocsVisionClient1988.msi" /qn TRANSFORMS="%opk-docs%\DocsVisionClient1988vpn.mst" ALLUSERS=1
msiexec /i "%opk-docs%\WorkflowClient1988.msi" /qn ALLUSERS=1
msiexec /i "%opk-docs%\TakeOfficeClient1988.msi" /qn TRANSFORMS="%opk-docs%\TakeOfficeClient1988vpn.mst" ALLUSERS=1
msiexec /i "%opk-docs%\InlookSetup.msi" /qn ALLUSERS=1

rem Пинги нужны, потому что InlookSetup.msi не ждёт завершения своей установки
ping 127.0.0.1 -n 20

rem Удаляем ненужные ярлыки
del "%public%\Desktop\DocsVision 4.5 Navigator.lnk"
del "%allusersprofile%\Рабочий стол\DocsVision 4.5 Navigator.lnk"

rem Прописываем путь к обновлениям программы в реестре
reg add HKLM\Software\Wow6432Node\iDoc\Inlook /v UpdateServiceUrl /t REG_SZ /d net.tcp://192.168.2.3:5556/UpdateService /f

rem Создаём папку для файла с логином и паролем
mkdir "%appdata%\IFP Navigator"

rem Копируем подготовленный файл с логином и паролем пользователя
copy /Y "%opk-docs%\dv.config" "%appdata%\IFP Navigator\"

pause
</code>
==== Для внешних пользователей ====
Все действия нужно выполнять в профиле потенциального пользователя СЭД.

Установите iDoc Inlook:
  - Распакуйте архив на рабочий стол (после распаковки на рабочем столе должна быть папка external, в которой находятся файлы).
  - Установите компонент dotNetFx40_Full_x86_x64.
  - Отредактируйте в Блокноте файл dv.config, подставив туда значения имени пользователя DocsVision и пароля (совпадает с логином и паролем на вход на рабочий компьютер). Сохраните файл с изменениями поверх старого.
  - Далее необходимо узнать, как называется папка, где лежит профиль пользователя. Для этого нужно зайти на системный диск в папку Users (в большинстве случаев C:\Users, и найти название папки профиля – например, i.ivanov). Альтернативный способ – запустить командную строку, и там будет написан путь к профилю.
  - Запустите install.cmd от имени администратора. Введите название папки профиля в ответ на появившийся запрос и нажмите Enter. Дождитесь сообщения «Для продолжения нажмите любую клавишу...», и нажмите Enter.

Запустите на рабочем столе ярлык iDoc Inlook.

install.cmd
<code dos>
@echo off
rem Задаём пути к папкам
set /P user=Введите название папки, где лежит профиль пользователя (например, a.ivanov):
set opk-docs=%systemdrive%\Users\%user%\Desktop\external
set ifp=%systemdrive%\Users\%user%\AppData\Roaming

rem Устанавливаем компоненты
msiexec /i "%opk-docs%\Prerequisites.msi" /qn ALLUSERS=1
msiexec /i "%opk-docs%\DocsVisionClient1988.msi" /qn TRANSFORMS="%opk-docs%\DocsVisionClient1988external.mst" ALLUSERS=1
msiexec /i "%opk-docs%\WorkflowClient1988.msi" /qn ALLUSERS=1
msiexec /i "%opk-docs%\TakeOfficeClient1988.msi" /qn TRANSFORMS="%opk-docs%\TakeOfficeClient1988external.mst" ALLUSERS=1
msiexec /i "%opk-docs%\InlookSetup.msi" /qn TRANSFORMS="%opk-docs%\InlookSetup_external.mst" ALLUSERS=1

rem Пинги нужны, потому что InlookSetup.msi не ждёт завершения своей установки
ping 127.0.0.1 -n 20

rem Удаляем ненужные ярлыки
del "%public%\Desktop\DocsVision 4.5 Navigator.lnk"
del "%allusersprofile%\Рабочий стол\DocsVision 4.5 Navigator.lnk"

rem Прописываем путь к обновлениям программы в реестре
reg add HKLM\Software\Wow6432Node\iDoc\Inlook /v UpdateServiceUrl /t REG_SZ /d net.tcp://doc.domain.ru:5556/UpdateService /f

rem Создаём папку для файла с логином и паролем
mkdir "%ifp%\IFP Navigator"

rem Копируем подготовленный файл с логином и паролем пользователя
copy /Y "%opk-docs%\dv.config" "%ifp%\IFP Navigator\"

pause
</code>

===== Удаление =====
<code dos>
wmic product where vendor="iDoc" call uninstall /nointeractive
wmic product where vendor="DocsVision" call uninstall /nointeractive
</code>